Exercício resolvido algoritmo VISUALG

 Faça um Algoritmo que Tenha um menu de opções que mostre as seguintes opções ao usuário.
1 – Somar 2 números 
2 – Média com Vários Números 
3 – Subtrair
4 – Dividir (testar divisão por zero)
5 – Multiplicar 
6 – Resto da Divisão (testar divisão zero) 
7 – Sair do Programa O programa só termina quando o usuário escolher a opção 7, enquanto não fizer isso o programa deverá mostrar o menu de opções novamente sempre que executar uma ação.




algoritmo "Exercício"
var
op: inteiro

   procedimento soma()
   var
   v1, v2, somaprocedimento: real
   inicio
       escreva("Para somar, insira o primeiro número: ")
       leia(v1)
       escreva("Insira o segundo número: ")
       leia (v2)
       somaprocedimento <- v1 + v2
       escreva ("A soma dos dois valores é: ",somaprocedimento)
       
   fimprocedimento

   procedimento procmedia()
   var
   varmedia, somamed, ndigitado: real
   qnotas: inteiro
   inicio
        escreva("Calcular média")
        qnotas <- 0
        varmedia <- 0
        somamed <- 0
   repita
        limpatela
        escreva ("Insira um valor, ou 0 para sair:")
        leia (ndigitado)
        se ndigitado <> 0 entao
        qnotas <- qnotas + 1
        somamed <- somamed + ndigitado
        varmedia <- somamed / qnotas
        fimse
   ate ndigitado = 0
   escreval("A média é: ", varmedia)
   fimprocedimento
   
   procedimento subtrair()
   var
   v1, v2, subtracao: real
   inicio
       escreva("para subtrair, insira o primeiro valor: ")
       leia (v1)
       escreva("insira o segundo valor: ")
       leia (v2)
       subtracao <- (v1 - v2)
       escreva("O resultado da subtração é: ", subtracao)
       
   fimprocedimento
   
   procedimento dividir()
   var
   v1, v2, divisao: real
   inicio
        escreva ("Para dividir, insira o primeiro valor: ")
        leia (v1)
        escreva ("insira o segundo valor: ")
        leia (v2)
        enquanto v2 = 0 faca
        escreva ("Não é possível usar 0 na divisão, insira outro número: ")
        leia (v2)
        fimenquanto
        divisao <- v1 / v2
        escreva ("O resultado da divisão é: ",divisao)
   fimprocedimento
   
   procedimento multiplicar()
   var
   v1, v2, multiplicacao: real
   inicio
        escreva("Para multiplicar, insira o primeiro valor: ")
        leia (v1)
        escreva("Insira o segundo valor: ")
        leia (v2)
        multiplicacao <- v1 * v2
        escreva("O valor da multiplicação é:", multiplicacao)
        escreva
   fimprocedimento

   procedimento resto()
var
v1, v2, quociente, restante: inteiro

inicio
      escreval ("Insira o primeiro valor: ")
      leia (v1)
      escreval ("Insira o segundo valor: ")
      leia (v2)
       enquanto v2 = 0 faca
       escreva ("Não é possível usar 0 na divisão, insira outro número: ")
       leia (v2)
       fimenquanto
      quociente <- int (v1/v2)
      restante <- (v1%v2)
      escreval("Resto: ", restante)
fimprocedimento
   
   funcao menu():inteiro
   var opcao :inteiro
   inicio

    escreval()
    escreval("_____________________________________")
       escreval()
       escreval("Menu de opções")
       escreval("1 - Somar")
       escreval("2 - Média")
       escreval("3 - Subtrair")
       escreval("4 - Dividir")
       escreval("5 - Multiplicar")
       escreval("6 - Resto da divisão")
       escreval("7 - Sair")
       escreva("Digite uma das opções do menu: ")
       leia(opcao)
       retorne opcao
   fimfuncao
inicio
    op <- menu()
    enquanto op <> 7 faca
    limpatela
        escolha op
           caso 1
               soma()
           caso 2
               procmedia()
           caso 3
               subtrair()
           caso 4
               dividir()
           caso 5
               multiplicar()
           caso 6
               resto()
           outrocaso
               escreval("Opção Invalida")
        fimescolha
        op <- menu()
    fimenquanto
fimalgoritmo